label outside:
    play music "/audio/intros/Intro - Once Again (Bensound).ogg" noloop
    queue music "/audio/loops/Loop - Once Again (Bensound).ogg"
    show bg alppi with transition_fade
    "Leo part en direction du domicile de Mari."
    "Il est 9 heures. La température de l'air avoisine les -9°C. Les gens frileux n'aimeront pas sortir sous une telle fraîcheur. Les Finlandais, eux, sont habitués à ça."
    "Leo prend un raccourci et passe par le Parc Alppi. Il a l'impression d'être suivi."
    "Leo se retourne et fait une rencontre plutôt étonnante..."
    show leo n at left with moveinleft
    show chat at right with moveinright
    play sound "/audio/sounds/Mron.mp3"
    "Chat" "Mron ?"
    l "Salut, toi !"
    "Ce chat l'a suivi à travers les allées du parc."
    show leo s
    l "Qu'est-ce que c'était que cette sensation ?"
    "Leo se repasse continuellement le moment où il a découvert le corps pendu de Valt ; tout en regardant le chat."
    show leo n
    l "Non, je dois rester concentré."
    hide leo with moveoutleft
    play sound "/audio/sounds/MronMaoh.mp3"
    "Chat" "Mron miaou !"
    "Le départ de Leo rend le chat triste. Il aurait tant voulu jouer avec Leo."
    hide chat with moveoutright
    "Le chat se décide à partir à cause du froid."
    "Leo atteint la maison de Mari, située dans une rue un peu en retrait de Helsinki."
    stop music fadeout 1.5
    show bg appartements with transition_fade
    show leo n at left with moveinleft
    l "Voilà l'appartement de Mari."
    "Leo appréhende la rencontre avec son amie. A-t-elle vraiment un lien avec la mort de Valt ?"
    "Drrrrrrrrring !"
    pause 2.0
    "Interphone" "Oui ?"
    l "Mari ? C'est Leo."
    m "Je descends."
    "Leo attend dehors sous le froid."
    show mari n at right with moveinright
    m "Salut, Leo."
    "Mari est une amie emo des garçons. Elle a vite abandonné ses études d'infirmière car elle ne se voyait pas du tout dans cette branche."
    "Elle passe ses journées à ne rien faire chez elle. Et pourtant, comment fait-elle pour payer son loyer ? Cela ne regarde personne."
    l "Mari. Y a quelque chose qui me tracasse..."
    m "Entre."
    "Leo entre chez Mari."
    jump mari_house

label mari_house:
    show bg mari with dissolve
    show leo n at left with moveinleft
    show mari n at right with moveinright
    m "Voilà. Qu'y a-t-il ?"
    "Leo ne voudrait pas brusquer Mari en l'accusant d'être venue chez lui peu avant le suicide de Valt. Il préfère plutôt y aller très progressivement."
    l "Mari. Je suis encore tourmenté par la mort de Valt. Je n'arrête pas de me repasser la scène où j'ai découvert son corps pendu."
    m "C'est plutôt normal. Ça fait toujours mal de perdre un être cher."
    m "Assieds-toi, ça va aller."
    hide mari n with moveoutright
    pause 1.0
    hide leo n with moveoutleft
    "Mari fait asseoir Leo tandis qu'elle se dirige sur son balcon pour aller fumer. C'est une opportunité en or pour fouiller partout et déterminer si Mari est vraiment liée au suicide de Valt."
    
    "Tutoriel" "Comme chez Leo et Valt, trois objets sont à trouver dans cette pièce. Avec les trois objets supplémentaires en possession, vous parviendrez sûrement à rétablir la vérité."
    call screen imagemap_mari

label notebook_found:
    if scene_notebook == False:
        $ scene_notebook = True
        $ leo_inventory.append(item_notebook)
        play sound "/audio/sounds/Indice.mp3"
        $ items_found += 1
        show screen inventory
        "Objet trouvé: carnet"
    l "Ça ne serait pas le carnet de Valt ? Pourquoi Mari l'a-t-il ?"
    l "Valt note ses mots de passe dedans."
    l "Hum..."
    "Leo feuillette le carnet et découvre le mot de passe du téléphone. 9753."
    l "Comme j'ai le mot de passe du téléphone de Valt, je peux maintenant le déverrouiller !"
    "Leo saisit le mot de passe 9753 et réussit à déverrouiller le portable de Valt."
    "Leo se dirige intuitivement vers les messages de Valt et découvre une communication intrigante... avec Mari !"
    l "La dernière communication date de deux heures avant que je ne découvre son corps !"
    m "\"J'ai besoin de te voir chez toi. On doit parler de quelque chose d'important.\""
    v "\"D'accord. Je serai là.\""
    "Leo soupçonne de plus en plus Mari d'avoir participé au suicide de Valt."
    jump keep_searching_2

label mari_phone_found:
    menu look_phone:
        l "Le portable de Mari. Je sais pas si je devrais fouiller dedans..."
        "Regarder":
            if scene_mari_phone == False:
                $ scene_mari_phone = True
                $ leo_inventory.append(item_mari_phone)
                play sound "/audio/sounds/Indice.mp3"
                $ items_found += 1
                show screen inventory
                "Objet trouvé: téléphone de Mari"
            l "Grah, son téléphone est verrouillé par un mot de passe !"
            if scene_notebook == True:
                l "Mais ça n'a pas vraiment d'importance. J'ai pu trouver la dernière conversation sur le téléphone de Valt."
        "Ne rien faire":
            l "Je ne devrais pas fouiller dans son portable à son insu !"
    jump keep_searching_2

label pills_found:
    if scene_pills == False:
        $ scene_pills = True
        $ leo_inventory.append(item_pills)
        play sound "/audio/sounds/Indice.mp3"
        $ items_found += 1
        show screen inventory
        "Objet trouvé: somnifères"
    l "Des somnifères ? C'est peut-être ça qu'il y avait dans le verre chez nous ?"
    "Leo parvient à associer les somnifères et la poudre verte trouvée au fond du verre."
    l "Donc, Mari a donné ses somnifères à Valt. Mais pourquoi ?"
    jump keep_searching_2

label gun_found:
    l "Putain. Mari a un pistolet sur elle ! Et en plus il est bien dissimulé !"
    menu move_gun:
        l "J'ai un très mauvais pressentiment..."
        "Déplacer le pistolet":
            $ gun_moved = True
            "Leo prend le pistolet et le cache sous le canapé."
            show bg mari deux
            hide screen imagemap_mari
            call screen imagemap_mari_2
        "Ne rien faire":
            l "La mort de Valt me tourmente beaucoup. Je dois me calmer."
    jump keep_searching_2

label keep_searching_2:
    if items_found < 7:
        hide screen inventory
        l "Je suis sûr qu'il y a encore d'autres indices cachés chez Mari."
        if gun_moved == True:
            call screen imagemap_mari_2
        else:
            call screen imagemap_mari
    else:
        hide screen imagemap_mari
        hide screen inventory
        show leo n at left with moveinleft
        show mari n at right with moveinright
        "Mari retourne à l'intérieur. Leo est sûr, elle était présente peu avant la mort de Valt !"
        show leo c at left with moveinleft
        l "Mari. Tu as tué Valt. J'en suis sûr.{w=2}{nw}"
        if gun_moved:
            jump good_ending
        else:
            jump bad_ending